//+------------------------------------------------------------------+

//| RiskGuard_Config1_Demo.mq5                                       |

//+------------------------------------------------------------------+

#property indicator_chart_window

#property indicator_plots 0

 

//+------------------------------------------------------------------+

//| Demo indicator for RiskGuard Strategy - Config. 1                |

//|                                                                  |

//| This indicator is only an educational example.                   |

//| It does not open, close or modify trades directly.               |

//|                                                                  |

//| All trading operations are handled exclusively by RiskGuard.     |

//|                                                                  |

//| The purpose of this demo is to show how an external indicator    |

//| can send BUY, SELL, BE and CLOSE commands to RiskGuard Config. 1 |

//| using the official RiskGuard protocol.                           |

//+------------------------------------------------------------------+

 

enum RG_CONFIG1_ACTION

{

   ACTION_NONE  = 0,

   ACTION_BUY   = 1,

   ACTION_SELL  = 2,

   ACTION_BE    = 3,

   ACTION_CLOSE = 4

};

 

//--- FIRST DEMO SIGNAL

input string First_Signal_Time = "08:00:00";// Format HH:MM:SS using broker/server time.

input RG_CONFIG1_ACTION First_Signal_Action = ACTION_BUY;// Action sent at First_Signal_Time.

 

//--- NEXT DEMO SIGNALS

input int Signal_02_Seconds_After_First = 60;// 60 = signal 2 starts 1 minute after the first signal.

input RG_CONFIG1_ACTION Signal_02_Action = ACTION_BUY;// Action for signal 2.

 

input int Signal_03_Seconds_After_First = 120;// 120 = signal 3 starts 2 minutes after the first signal.

input RG_CONFIG1_ACTION Signal_03_Action = ACTION_BUY;// Action for signal 3.

 

input int Signal_04_Seconds_After_First = 180;// 180 = signal 4 starts 3 minutes after the first signal.

input RG_CONFIG1_ACTION Signal_04_Action = ACTION_BUY;// Action for signal 4.

 

input int Signal_05_Seconds_After_First = 240;// 240 = signal 5 starts 4 minutes after the first signal.

input RG_CONFIG1_ACTION Signal_05_Action = ACTION_NONE;// Action for signal 5.

 

input int Signal_06_Seconds_After_First = 300;// 300 = signal 6 starts 5 minutes after the first signal.

input RG_CONFIG1_ACTION Signal_06_Action = ACTION_NONE;// Action for signal 6.

 

input int Signal_07_Seconds_After_First = 360;// 360 = signal 7 starts 6 minutes after the first signal.

input RG_CONFIG1_ACTION Signal_07_Action = ACTION_NONE;// Action for signal 7.

 

input int Signal_08_Seconds_After_First = 420;// 420 = signal 8 starts 7 minutes after the first signal.

input RG_CONFIG1_ACTION Signal_08_Action = ACTION_NONE;// Action for signal 8.

 

input int Signal_09_Seconds_After_First = 480;// 480 = signal 9 starts 8 minutes after the first signal.

input RG_CONFIG1_ACTION Signal_09_Action = ACTION_NONE;// Action for signal 9.

 

input int Signal_10_Seconds_After_First = 540;// 540 = signal 10 starts 9 minutes after the first signal.

input RG_CONFIG1_ACTION Signal_10_Action = ACTION_CLOSE;// Action for signal 10.

 

datetime indicatorStartTime;

 

//+------------------------------------------------------------------+

int OnInit()

{

   indicatorStartTime = TimeCurrent();

 

   Print("[RG DEMO CONFIG 1] Indicator started",

         " | Symbol=", _Symbol,

         " | StartTime=", TimeToString(indicatorStartTime, TIME_DATE|TIME_SECONDS));

 

   return INIT_SUCCEEDED;

}

 

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

{

   if(reason == REASON_CHARTCHANGE)

      return;

 

   CleanupIndicatorResources();

 

   Print("[RG DEMO CONFIG 1] Indicator stopped and resources cleaned | Symbol=", _Symbol);

}

 

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

{

   datetime firstTime = BuildTodayTime(First_Signal_Time);

 

   if(firstTime <= 0)

      return rates_total;

 

   CheckSlot(1,  firstTime,                                 First_Signal_Action);

   CheckSlot(2,  firstTime + Signal_02_Seconds_After_First, Signal_02_Action);

   CheckSlot(3,  firstTime + Signal_03_Seconds_After_First, Signal_03_Action);

   CheckSlot(4,  firstTime + Signal_04_Seconds_After_First, Signal_04_Action);

   CheckSlot(5,  firstTime + Signal_05_Seconds_After_First, Signal_05_Action);

   CheckSlot(6,  firstTime + Signal_06_Seconds_After_First, Signal_06_Action);

   CheckSlot(7,  firstTime + Signal_07_Seconds_After_First, Signal_07_Action);

   CheckSlot(8,  firstTime + Signal_08_Seconds_After_First, Signal_08_Action);

   CheckSlot(9,  firstTime + Signal_09_Seconds_After_First, Signal_09_Action);

   CheckSlot(10, firstTime + Signal_10_Seconds_After_First, Signal_10_Action);

 

   return rates_total;

}

 

//+------------------------------------------------------------------+

//| Checks if a demo signal must be sent to RiskGuard Config. 1       |

//+------------------------------------------------------------------+

void CheckSlot(int slot, datetime targetTime, RG_CONFIG1_ACTION action)

{

   if(action == ACTION_NONE)

      return;

 

   // Prevent retroactive signals.

   if(targetTime < indicatorStartTime)

      return;

 

   datetime now = TimeCurrent();

 

   // Works in live market and Strategy Tester.

   // The signal is sent at the first available tick after targetTime.

   if(now < targetTime)

      return;

 

   string lastName = LastSignalGVName(slot);

 

   if(GlobalVariableCheck(lastName))

   {

      datetime lastValue = (datetime)GlobalVariableGet(lastName);

 

      if(lastValue == targetTime)

         return;

   }

 

   // Save before sending the command to prevent duplicates.

   GlobalVariableSet(lastName, (double)targetTime);

 

   string actionText = ActionToString(action);

 

   if(actionText == "")

      return;

 

   if(actionText == "BUY")

      SendRiskGuardConfig1Signal("BUY");

 

   else if(actionText == "SELL")

      SendRiskGuardConfig1Signal("SELL");

 

   else if(actionText == "BE")

      SendRiskGuardConfig1Signal("BE");

 

   else if(actionText == "CLOSE")

      SendRiskGuardConfig1Signal("CLOSE");

 

   Print("[RG DEMO CONFIG 1] Signal sent",

         " | Slot=", slot,

         " | TargetTime=", TimeToString(targetTime, TIME_DATE|TIME_SECONDS),

         " | Action=", actionText,

         " | Symbol=", _Symbol);

}

 

//+------------------------------------------------------------------+

string ActionToString(RG_CONFIG1_ACTION action)

{

   if(action == ACTION_BUY)

      return "BUY";

 

   if(action == ACTION_SELL)

      return "SELL";

 

   if(action == ACTION_BE)

      return "BE";

 

   if(action == ACTION_CLOSE)

      return "CLOSE";

 

   return "";

}

 

//+------------------------------------------------------------------+

string LastSignalGVName(int slot)

{

   return "RG_Demo_Config1_LastSignal_" + _Symbol + "_" + IntegerToString(slot);

}

 

//+------------------------------------------------------------------+

void CleanupIndicatorResources()

{

   for(int i = 1; i <= 10; i++)

      GlobalVariableDel(LastSignalGVName(i));

 

   // Delete here any graphic object created by this indicator.

   // Example:

   // ObjectDelete(0, "RG_Demo_Config1_Box");

   // ObjectDelete(0, "RG_Demo_Config1_Label");

}

 

//+------------------------------------------------------------------+

datetime BuildTodayTime(string signalTime)

{

   string parts[];

   int count = StringSplit(signalTime, ':', parts);

 

   if(count != 3)

   {

      Print("[RG DEMO CONFIG 1] Invalid time format: ", signalTime,

            " | Correct format: HH:MM:SS");

      return 0;

   }

 

   int h = (int)StringToInteger(parts[0]);

   int m = (int)StringToInteger(parts[1]);

   int s = (int)StringToInteger(parts[2]);

 

   if(h < 0 || h > 23 || m < 0 || m > 59 || s < 0 || s > 59)

   {

      Print("[RG DEMO CONFIG 1] Invalid time value: ", signalTime);

      return 0;

   }

 

   MqlDateTime dt;

   TimeToStruct(TimeCurrent(), dt);

 

   dt.hour = h;

   dt.min  = m;

   dt.sec  = s;

 

   return StructToTime(dt);

}

 

//+------------------------------------------------------------------+

//| Official RiskGuard signal function  Config. 1                    |

//|                                                                  |

//|                                                                  |

//| DO NOT MODIFY THIS FUNCTION.                                     |

//| This function must remain identical in all RiskGuard-compatible  |

//| indicators.                                                      |

//+------------------------------------------------------------------+

void SendRiskGuardConfig1Signal(string action)

{

   GlobalVariableDel("RG_Strategy_Config1_Buy_" + _Symbol);

   GlobalVariableDel("RG_Strategy_Config1_Sell_" + _Symbol);

   GlobalVariableDel("RG_Strategy_Config1_Close_" + _Symbol);

   GlobalVariableDel("RG_Strategy_Config1_Be_" + _Symbol);

 

   if(action == "BUY")

      GlobalVariableSet("RG_Strategy_Config1_Buy_" + _Symbol, 1);

 

   else if(action == "SELL")

      GlobalVariableSet("RG_Strategy_Config1_Sell_" + _Symbol, 1);

 

   else if(action == "CLOSE")

      GlobalVariableSet("RG_Strategy_Config1_Close_" + _Symbol, 1);

 

   else if(action == "BE")

      GlobalVariableSet("RG_Strategy_Config1_Be_" + _Symbol, 1);

 

   else

      Print("[RG CONFIG 1] Invalid action: ", action);

}

//+------------------------------------------------------------------+